Làm thế nào để nhanh chóng chuyển đổi số tiền tệ sang từ trong Excel?

Giả sử bạn có một dãy số đơn vị tiền tệ cần thiết để chuyển đổi thành văn bản từ trong Excel, và bạn có bất kỳ thủ thuật nhanh nào để giải quyết nhanh không? Bây giờ hướng dẫn này cho bạn biết một số cách dễ dàng để chuyển đổi nhiều số tiền tệ sang các từ tiếng Anh cùng một lúc trong Excel.

Đánh vần các số đơn vị tiền tệ thành các từ có VBA dài

Đánh vần các số tiền tệ thành các từ với chức năng Numbers to Words tiện dụng

Đánh vần các số đơn vị tiền tệ thành các từ có VBA dài

Trong Excel, bạn không thể nhanh chóng chuyển đổi số sang từ tiếng Anh ngoại trừ VBA.

1. nhấn Alt + F11 phím để mở Microsoft Visual Basic cho ứng dụng cửa sổ.

2. nhấp chuột Chèn > Mô-đun và dán bên dưới VBA vào Mô-đun cửa sổ.

VBA: Chuyển đổi số tiền tệ sang từ tiếng Anh.

Function SpellNumberToEnglish(ByVal pNumber)
'Updateby20131113
Dim Dollars, Cents
arr = Array("", "", " Thousand ", " Million ", " Billion ", " Trillion ")
pNumber = Trim(Str(pNumber))
xDecimal = InStr(pNumber, ".")
If xDecimal > 0 Then
    Cents = GetTens(Left(Mid(pNumber, xDecimal + 1) & "00", 2))
    pNumber = Trim(Left(pNumber, xDecimal - 1))
End If
xIndex = 1
Do While pNumber <> ""
    xHundred = ""
    xValue = Right(pNumber, 3)
    If Val(xValue) <> 0 Then
        xValue = Right("000" & xValue, 3)
        If Mid(xValue, 1, 1) <> "0" Then
            xHundred = GetDigit(Mid(xValue, 1, 1)) & " Hundred "
        End If
        If Mid(xValue, 2, 1) <> "0" Then
            xHundred = xHundred & GetTens(Mid(xValue, 2))
        Else
            xHundred = xHundred & GetDigit(Mid(xValue, 3))
        End If
    End If
    If xHundred <> "" Then
        Dollars = xHundred & arr(xIndex) & Dollars
    End If
    If Len(pNumber) > 3 Then
        pNumber = Left(pNumber, Len(pNumber) - 3)
    Else
        pNumber = ""
    End If
    xIndex = xIndex + 1
Loop
Select Case Dollars
    Case ""
        Dollars = "No Dollars"
    Case "One"
        Dollars = "One Dollar"
    Case Else
        Dollars = Dollars & " Dollars"
End Select
Select Case Cents
    Case ""
        Cents = " and No Cents"
    Case "One"
        Cents = " and One Cent"
    Case Else
        Cents = " and " & Cents & " Cents"
End Select
SpellNumberToEnglish = Dollars & Cents
End Function
Function GetTens(pTens)
Dim Result As String
Result = ""
If Val(Left(pTens, 1)) = 1 Then
    Select Case Val(pTens)
        Case 10: Result = "Ten"
        Case 11: Result = "Eleven"
        Case 12: Result = "Twelve"
        Case 13: Result = "Thirteen"
        Case 14: Result = "Fourteen"
        Case 15: Result = "Fifteen"
        Case 16: Result = "Sixteen"
        Case 17: Result = "Seventeen"
        Case 18: Result = "Eighteen"
        Case 19: Result = "Nineteen"
        Case Else
    End Select
Else
Select Case Val(Left(pTens, 1))
    Case 2: Result = "Twenty "
    Case 3: Result = "Thirty "
    Case 4: Result = "Forty "
    Case 5: Result = "Fifty "
    Case 6: Result = "Sixty "
    Case 7: Result = "Seventy "
    Case 8: Result = "Eighty "
    Case 9: Result = "Ninety "
    Case Else
End Select
Result = Result & GetDigit(Right(pTens, 1))
End If
GetTens = Result
End Function
Function GetDigit(pDigit)
Select Case Val(pDigit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
    Case Else: GetDigit = ""
End Select
End Function

3. Sau đó lưu mã này và đóng cửa sổ để quay lại trang tính và chọn một ô trống, nhập công thức này = SpellNumberToEnglish (A2) (A2 là số đơn vị tiền tệ) và nhấn đăng ký hạng mục thi , sau đó kéo chốt điền xuống để áp dụng công thức này cho các ô bạn cần. Xem ảnh chụp màn hình:

Đánh vần số tiền tệ thành các từ với chức năng Đánh vần số tiện dụng

Nếu bạn cần thường xuyên chuyển đổi số thành từ, phương pháp trên không phải là cách tốt và thuận tiện cho bạn. Tuy nhiên, bạn có thể sử dụng Số thành từ chức năng chuyển đổi nhanh số tiền tệ sang từ tiếng Anh hoặc từ tiếng Trung nếu bạn có Kutools cho Excel.

Sau cài đặt miễn phí Kutools cho Excel, vui lòng làm như sau:

1. Chọn số đơn vị tiền tệ và nhấp vào Kutools > Nội dung > Số thành từ. Xem ảnh chụp màn hình:

2. bên trong Số cho từ tiền tệ hộp thoại, kiểm tra Tiếng Anh or Trung Quốc tùy chọn như bạn cần. Xem ảnh chụp màn hình:

3. nhấp chuột Ok or Đăng Nhập. Sau đó, các số đơn vị tiền tệ bạn chọn đã được chuyển đổi thành từ.

Số tiền tệ sang từ tiếng Anh

Số tiền tệ sang từ tiếng Trung

Lưu ý: bạn có thể sao chép và dán các số đơn vị tiền tệ vào một trang tính khác trước khi áp dụng Số cho Từ

  Chuyển đổi số tiền tệ thành từ