Làm thế nào để tìm và thay thế văn bản trong tài liệu Word từ Excel?
Trong tài liệu Word, chúng ta có thể áp dụng chức năng Tìm và Thay thế để tìm và thay thế một văn bản nhanh chóng. Tuy nhiên, nếu có nhiều văn bản cần tìm và thay thế, hãy nhập từng văn bản một vào tính năng Tìm và Thay thế sẽ rất tốn thời gian. Trong trường hợp này, bạn có thể nhập văn bản tìm và thay thế vào danh sách ô và với sự trợ giúp của mã VBA trong Excel để thực hiện công việc này một cách dễ dàng. Trong bài viết này, tôi cũng sẽ giới thiệu một tính năng hữu ích để tìm và thay thế hàng loạt văn bản trong nhiều tài liệu Word.
Tìm và thay thế nhiều văn bản trong một tài liệu Word từ Excel bằng mã VBA
Tìm và thay thế nhiều văn bản trong nhiều tài liệu Word từ Excel bằng mã VBA
Tìm và thay thế nhiều văn bản trong nhiều tài liệu Word với một tính năng mạnh mẽ
Tìm và thay thế nhiều văn bản trong một tài liệu Word từ Excel bằng mã VBA
Nếu bạn muốn tìm và thay thế một số văn bản chỉ trong một tệp Word, mã VBA sau đây có thể giúp bạn.
1. Trong trang tính Excel, hãy tạo một cột chứa văn bản bạn muốn tìm và thay thế và một cột khác có văn bản để thay thế như hình minh họa bên dưới. Và sau đó nhấn Alt + F11 các phím đồng thời để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.
2. Sau đó nhấn vào Chèn > Mô-đun, sao chép và dán mã VBA bên dưới vào cửa sổ.
Mã VBA: Tìm và thay thế nhiều văn bản trong một tệp Word
Sub replace_texts_range_of_cells()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFileDlg As FileDialog
On Error GoTo ExitSub
Set xFileDlg = Application.FileDialog(msoFileDialogFilePicker)
xFileDlg.AllowMultiSelect = False
xFileDlg.Filters.Add "Word Document", "*.docx; *.doc; *.docm"
xFileDlg.FilterIndex = 2
If xFileDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges):", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
(xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
GoTo ExitSub
End If
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
Set xDoc = xWordApp.Documents.Open(xFileDlg.SelectedItems.Item(1))
For I = 1 To xRng.Areas.Item(1).Cells.Count
With xDoc.Application.Selection.Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = xRng.Areas.Item(1).Cells.Item(I).Value
.Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchByte = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
Next
ExitSub:
Set xRng = Nothing
Set xFileDlg = Nothing
Set xWordApp = Nothing
Set xDoc = Nothing
End Sub
3. Sau khi dán mã, vẫn còn trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp CÔNG CỤ > dự án, xem ảnh chụp màn hình:
4. Trong cửa sổ bật ra Tài liệu tham khảo - VBAProject hộp thoại, chọn Thư viện đối tượng Microsoft Word 16.0 từ hộp danh sách, xem ảnh chụp màn hình:
5. Nhấp chuột OK để đóng hộp thoại và bây giờ, nhấn F5 để chạy mã này, trong cửa sổ Duyệt qua bật lên, chọn Tệp Word bạn muốn thay thế văn bản, xem ảnh chụp màn hình:
6. Sau đó nhấn vào OK, trong hộp thoại sau, nhấn Ctrl để chọn riêng văn bản gốc và ô văn bản mới mà bạn muốn sử dụng, xem ảnh chụp màn hình:
7. Và sau đó, nhấp vào OK , bây giờ, các văn bản được tìm thấy và thay thế bằng các văn bản mới trong tài liệu được chỉ định của bạn và tệp cũng đang mở, bạn nên lưu nó để giữ các thay đổi.
Tìm và thay thế nhiều văn bản trong nhiều tài liệu Word từ Excel bằng mã VBA
Ở đây, tôi cũng tạo mã VBA để tìm và thay thế nhiều văn bản trong nhiều tài liệu Word, vui lòng thực hiện như sau:
1. Mở tệp Excel có chứa hai cột giá trị để thay thế và thay thế bằng như hình ảnh chụp màn hình bên dưới, sau đó nhấn Alt + F11 các phím đồng thời để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.
2. Sau đó nhấn vào Chèn > Mô-đun, sao chép và dán mã VBA bên dưới vào cửa sổ.
Mã VBA: Tìm và thay thế nhiều văn bản trong nhiều tệp Word
Sub FindReplaceAcrossMultipleWordDocuments()
'Updateby ExtendOffice
Dim xWordApp As Word.Application
Dim xDoc As Word.Document
Dim xRng As Range
Dim I As Integer
Dim xFolderDlg As FileDialog
Dim xFSO As Scripting.FileSystemObject
Dim xFile As File
On Error GoTo ExitSub
Set xFolderDlg = Application.FileDialog(msoFileDialogFolderPicker)
If xFolderDlg.Show <> -1 Then GoTo ExitSub
Set xRng = Application.InputBox("Please select the lists of find and replace texts (Press Ctrl key to select two same size ranges", "Kutools for Excel", , , , , , 8)
If xRng.Areas.Count <> 2 Then
MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size", vbInformation + vbOKOnly, "Kutools for Excel"
GoTo ExitSub
End If
If (xRng.Areas.Item(1).Rows.Count <> xRng.Areas.Item(2).Rows.Count) Or _
(xRng.Areas.Item(1).Columns.Count <> xRng.Areas.Item(2).Columns.Count) Then
MsgBox "Please select two columns (press Ctrl key), the two ranges have the same size.", vbInformation + vbOKOnly, "Kutools for Excel"
GoTo ExitSub
End If
Set xFSO = New Scripting.FileSystemObject
Set xWordApp = CreateObject("Word.application")
xWordApp.Visible = True
For Each xFile In xFSO.GetFolder(xFolderDlg.SelectedItems(1)).Files
If VBA.InStr(xFile.Type, "Microsoft Word") > 0 Then
Set xDoc = xWordApp.Documents.Open(xFile.Path)
For I = 1 To xRng.Areas.Item(1).Cells.Count
With xDoc.Application.Selection.Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = xRng.Areas.Item(1).Cells.Item(I).Value
.Replacement.Text = xRng.Areas.Item(2).Cells.Item(I).Value
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchByte = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
xDoc.Application.Selection.Find.Execute Replace:=wdReplaceAll
Next
xDoc.Close wdSaveChanges
End If
Next
xWordApp.Quit
MsgBox "The Find and Replace has been completed", vbInformation + vbOKOnly, "Kutools for Excel"
ExitSub:
Set xRng = Nothing
Set xFolderDlg = Nothing
Set xWordApp = Nothing
Set xDoc = Nothing
End Sub
3. Vẫn trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp CÔNG CỤ > dự án, Trong Tài liệu tham khảo - VBAProject hộp thoại, chọn Thư viện đối tượng Microsoft Word 16.0 và Thời gian chạy tập lệnh của Microsoft tùy chọn từ hộp danh sách, xem ảnh chụp màn hình:
4. Sau khi kiểm tra hai tùy chọn và nhấp vào OK để đóng hộp thoại và sau đó, tiếp tục nhấn F5 phím để thực thi mã này, khi mở Xem cửa sổ, chọn một thư mục chứa các tài liệu Word mà bạn muốn thực hiện tìm và thay thế, xem ảnh chụp màn hình:
5. Nhấp chuột OK , trong hộp thoại bật ra, nhấn Ctrl để chọn riêng văn bản gốc và cột văn bản mới mà bạn muốn sử dụng, xem ảnh chụp màn hình:
6. Cuối cùng, nhấp OKvà các văn bản gốc được thay thế bằng các văn bản mới trên các tệp luận văn, sau khi hoàn thành, một hộp thoại sẽ bật ra như ảnh chụp màn hình bên dưới:
7. Nhấp chuột OK để đóng hộp thoại. Và bạn có thể vào tệp để kiểm tra kết quả đã chuyển đổi.
Tìm và thay thế nhiều văn bản trong nhiều tài liệu Word với một tính năng mạnh mẽ
Phần này, tôi sẽ nói về cách tìm và thay thế hàng loạt văn bản trong nhiều tài liệu Word từ Word thay vì Excel. Với một công cụ mạnh mẽ-Kutools cho Word, bạn có thể nhanh chóng tìm và thay thế các văn bản cụ thể và thay thế chúng bằng các văn bản mới trong tệp chính, đầu trang, chân trang, nhận xét, v.v. và đánh dấu kết quả khi bạn cần.
1. Mở một tệp Word, sau đó bấm Kutools Plus > Tìm và thay thế hàng loạt, xem ảnh chụp màn hình:
2. Trong mở Tìm và thay thế hàng loạt hộp thoại, vui lòng thực hiện các thao tác sau:
- Nhấp chuột Thêm để thêm các tệp Word mà bạn muốn tìm và thay thế văn bản;
- Trong ngăn bên trái, nhấp vào Thêm dòng từ dải băng trên cùng;
- Trong trường đã chèn, hãy nhập văn bản gốc và văn bản mới vào Tìm kiếm và Thay thế các cột riêng biệt mà bạn muốn tìm và thay thế. Ngoài ra, bạn có thể chỉ định màu để đánh dấu các văn bản được thay thế khi bạn cần.
3. Sau khi tạo các tiêu chí tìm kiếm, hãy nhấp vào Thay thế nút để đi đến Xem trước kết quả để xem kết quả tìm và thay thế. Xem ảnh chụp màn hình:
4. Sau đó nhấn vào Đóng và một hộp nhắc xuất hiện để nhắc bạn nếu bạn muốn lưu trường hợp này, hãy nhấp vào Có để lưu nó và nhấp vào Không để bỏ qua nó, hãy xem ảnh chụp màn hình:
- Tìm và thay thế các ký tự đặc biệt trong nhiều tài liệu Word;
- Tìm và thay thế nhiều chuỗi với định dạng cụ thể trong nhiều tài liệu Word;
- Tìm và thay thế nhiều chuỗi trong nhiều tệp txt / htm / html.
Công cụ năng suất văn phòng tốt nhất
Nâng cao kỹ năng Excel của bạn với Kutools for Excel và trải nghiệm hiệu quả hơn bao giờ hết. Kutools for Excel cung cấp hơn 300 tính năng nâng cao để tăng năng suất và tiết kiệm thời gian. Bấm vào đây để có được tính năng bạn cần nhất...
Tab Office mang lại giao diện Tab cho Office và giúp công việc của bạn trở nên dễ dàng hơn nhiều
- Cho phép chỉnh sửa và đọc theo thẻ trong Word, Excel, PowerPoint, Publisher, Access, Visio và Project.
- Mở và tạo nhiều tài liệu trong các tab mới của cùng một cửa sổ, thay vì trong các cửa sổ mới.
- Tăng 50% năng suất của bạn và giảm hàng trăm cú nhấp chuột cho bạn mỗi ngày!
