Làm thế nào để lưu email dưới dạng định dạng ảnh (jpg / tiff) trong triển vọng?

Bạn đã bao giờ cố gắng lưu thư email dưới dạng ảnh chẳng hạn như ảnh jpg hoặc ảnh tiff trong Outlook chưa? Bài viết này sẽ chỉ cho bạn một phương pháp để giải quyết vấn đề này.

Lưu email dưới dạng hình ảnh với mã VBA

Lưu email dưới dạng hình ảnh với mã VBA

Vui lòng thực hiện như sau để lưu thư email dưới dạng ảnh trong Outlook.

1. Chọn một email bạn sẽ lưu dưới dạng ảnh, sau đó bấm Khác + F11 các phím đồng thời để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. bên trong Microsoft Visual Basic cho các ứng dụng cửa sổ, vui lòng nhấp vào Chèn > Biểu mẫu người dùng. Xem ảnh chụp màn hình:

3. Tạo một Biểu mẫu người dùng như ảnh chụp màn hình dưới đây.

4. Chọn Tùy chọn jpg và đổi tên nó thành opbJPG ở bên trái Bất động sản cửa sổ.

5. Lặp lại bước 4 ở trên để đổi tên nút tùy chọn khác thành opbTIFF. Và đổi tên OK nút lệnh và Hủy bỏ nút lệnh như cdbOk và cdb Hủy riêng biệt.

Chú thích: Nếu Bất động sản ngăn không hiển thị trong Microsoft Visual Basic cho các ứng dụng cửa sổ, vui lòng nhấp vào F4 để hiển thị ngăn.

6. Nhấp đúp vào bất kỳ khoảng trống nào trên biểu mẫu người dùng để mở Mã cửa sổ. Thay thế tất cả mã bằng tập lệnh VBA sau. Và sau đó đóng cửa sổ Mã.

Mã VBA 1: Lưu email dưới dạng hình ảnh

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. Chọn Người dùngForm1 và đổi tên nó thành FrmPicType trong Bất động sản ngăn như ảnh chụp màn hình bên dưới.

8. nhấp chuột Chèn > Mô-đun, và sau đó sao chép mã VBA bên dưới vào cửa sổ Mô-đun.

Mã VBA 2: Lưu email dưới dạng hình ảnh

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. nhấp chuột CÔNG CỤ > dự án, kiểm tra Thư viện đối tượng Microsoft PowerPoint hộp và sau đó nhấp vào OK cái nút. Xem ảnh chụp màn hình:

10. Nhấn nút F5 phím để chạy mã. Sau đó Người dùngForm1 hộp thoại bật lên, vui lòng chọn loại hình ảnh và nhấp vào OK cái nút. Xem ảnh chụp màn hình: