Làm cách nào để đánh dấu email chưa đọc cũ hơn những ngày cụ thể là đã đọc tự động trong Outlook?

Nếu có nhiều email chưa đọc trong thư mục Hộp thư đến của bạn, thông thường, bạn có thể áp dụng tính năng Đánh dấu tất cả là đã đọc để đánh dấu tất cả các email chưa đọc là email đã đọc theo cách thủ công. Tuy nhiên, bạn đã bao giờ cố gắng đánh dấu các email chưa đọc cũ hơn các ngày cụ thể là được đọc tự động trong Outlook mà không cần đặt thủ công mỗi lần chưa?

Đánh dấu các email chưa đọc cũ hơn những ngày cụ thể là đã đọc tự động bằng mã VBA

Đánh dấu các email chưa đọc cũ hơn những ngày cụ thể là đã đọc tự động bằng mã VBA

Để tự động đánh dấu tất cả các email chưa đọc cũ hơn những ngày cụ thể là đã đọc, mã VBA sau có thể giúp bạn:

1. Giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp đúp ĐâyOutlookSession từ Project1 (VbaProject.OTM) để mở chế độ, sau đó sao chép và dán mã bên dưới vào mô-đun trống.

Mã VBA: Tự động đánh dấu các email chưa đọc cũ hơn những ngày cụ thể là đã đọc:

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

Chú thích: Trong đoạn mã trên, bạn có thể thay đổi số ngày trong tập lệnh này: Nếu DateDiff ("d", xItems (i) .ReceiveTime, Now)> = 15 Sau đó theo nhu cầu của riêng bạn.

3. Sau đó, lưu và đóng cửa sổ mã này, kể từ đó, mỗi khi bạn khởi chạy Outlook, tất cả các email chưa đọc cũ hơn ngày xác định trước sẽ được đánh dấu là đã đọc tự động cùng một lúc.

Chú thích: Mã này chỉ có sẵn cho tài khoản dữ liệu mặc định.