Làm cách nào để trả lời bình thường trong thư mục các mục đã gửi từ Outlook? 

Thông thường, khi bạn nhấp vào tính năng Trả lời trong thư mục Mục đã gửi để gửi một thư bổ sung khác cho những người bạn đã gửi, địa chỉ email của chính bạn sẽ được hiển thị tại trường Đến như hình ảnh chụp màn hình sau. Điều này có thể gây khó chịu cho bạn mỗi lần thay đổi địa chỉ. Làm cách nào để Outlook sử dụng địa chỉ của người nhận ban đầu, không phải của bạn?

Trả lời bình thường trong thư mục Mục đã Gửi từ Outlook với tính năng Trả lời Tất cả

Trả lời bình thường trong thư mục Mục đã Gửi từ Outlook với mã VBA

---

Trả lời bình thường trong thư mục Mục đã Gửi từ Outlook với tính năng Trả lời Tất cả

Trong Outlook, Trả lời tất cả tính năng này có thể giúp bạn giải quyết vấn đề này, hãy làm như sau:

Khi bạn cần trả lời email đã gửi để gửi lại để giữ địa chỉ người nhận ban đầu, vui lòng nhấp vào Trả lời tất cả và địa chỉ của người nhận ban đầu được đặt tại Đến trường như ảnh chụp màn hình sau:

---

Trả lời bình thường trong thư mục Mục đã Gửi từ Outlook với mã VBA

Đôi khi, bạn có thể quên Trả lời tất cả tính năng khi trả lời tin nhắn đã gửi, vì vậy mã VBA dưới đây có thể giúp bạn trả lời bình thường trong thư mục Mục đã Gửi bằng cách sử dụng tính năng Trả lời. Thực hiện theo các bước sau:

1. Giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp đúp ĐâyOutlookSession từ Project1 (VbaProject.OTM) để mở chế độ, sau đó sao chép và dán mã sau vào mô-đun trống.

Mã VBA: Trả lời bình thường trong thư mục Mục đã Gửi từ Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Sau đó, lưu mã và khởi động lại Outlook để có hiệu lực mã, ngay bây giờ, khi nhấp vào đáp lại để gửi lại một email trong Các mục đã gửi thư mục, địa chỉ của người nhận ban đầu được hiển thị tại trường Đến khi bạn cần.