Làm cách nào để giữ danh mục trong khi trả lời hoặc chuyển tiếp email trong Outlook?

Thông thường, khi bạn trả lời hoặc chuyển tiếp một email mà tôi đã phân loại, danh mục sẽ tự động bị xóa trên email đã gửi. Nếu bạn muốn giữ danh mục email gửi đi trong việc trả lời hoặc chuyển tiếp, bài viết này sẽ giới thiệu một phương pháp để giải quyết nó.

Giữ danh mục trong khi trả lời hoặc chuyển tiếp email với mã VBA

Giữ danh mục trong khi trả lời hoặc chuyển tiếp email với mã VBA

1. Giữ phím tắt ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp đúp ĐâyOutlookSession từ Project1 (VbaProject.OTM) để mở chế độ, sau đó sao chép và dán mã sau vào mô-đun trống.

Mã VBA: Giữ danh mục trong khi trả lời hoặc chuyển tiếp email:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

doc giữ hạng mục trả lời 1

3. Sau đó, lưu và đóng cửa sổ mã này, đóng và khởi động lại Outlook, bây giờ, khi bạn trả lời hoặc chuyển tiếp email với danh mục, danh mục sẽ được giữ trong thư gửi đi trong Các mục đã gửi, xem ảnh chụp màn hình:

doc giữ hạng mục trả lời 2