Làm cách nào để xóa tất cả các danh mục khỏi Outlook?

Giả sử, có rất nhiều mục được áp dụng cho danh mục màu trong Outlook của bạn. Nếu bạn cần xóa tất cả các danh mục này khỏi các mục, làm cách nào bạn có thể giải quyết công việc này một cách nhanh chóng và dễ dàng trong Outlook?

Xóa tất cả danh mục khỏi một thư mục cụ thể với tính năng Xóa tất cả danh mục

Xóa tất cả các danh mục khỏi một tài khoản cụ thể bằng mã VBA

Xóa tất cả danh mục khỏi một thư mục cụ thể với tính năng Xóa tất cả danh mục

Nếu bạn chỉ cần xóa các danh mục trong một thư mục cụ thể, hãy làm như sau:

1. Bấm vào thư mục mà bạn muốn xóa các danh mục màu, sau đó bấm Ctrl + A để chọn tất cả các mục.

2. Sau đó bấm chuột phải, rồi chọn Phân loại > Xóa tất cả danh mục từ menu ngữ cảnh, xem ảnh chụp màn hình:

doc rõ ràng loại 1

3. Và sau đó, tất cả các danh mục màu trong thư mục cụ thể này đã bị xóa ngay lập tức.

Xóa tất cả các danh mục khỏi một tài khoản cụ thể bằng mã VBA

Để xóa tất cả các danh mục khỏi tất cả các mục, chẳng hạn như email, nhiệm vụ, danh bạ, ghi chú, v.v. khỏi tài khoản, mã VBA dưới đây có thể giúp bạn:

1. Nhấp vào email tài khoản mà bạn muốn xóa tất cả các danh mục, sau đó nhấn giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Nhấp chuột Chèn > Mô-đunvà dán macro sau vào Mô-đun Cửa sổ.

Mã VBA: Xóa tất cả các danh mục khỏi một tài khoản cụ thể:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Sau đó nhấn F5 để chạy nó, và sau đó một hộp nhắc xuất hiện để nhắc bạn tất cả các danh mục từ tài khoản đã chọn đã bị xóa, hãy xem ảnh chụp màn hình:

doc rõ ràng loại 2