Làm cách nào để lấy địa chỉ email của người gửi từ một hoặc nhiều email trong Outlook?

Bạn đã bao giờ cố gắng trích xuất địa chỉ email từ trường "Từ" của một hoặc nhiều email đã nhận trong Outlook chưa? Bài viết này cung cấp mã VBA để giúp bạn xử lý tác vụ này.

Lấy địa chỉ email của người gửi từ một hoặc nhiều email trong Outlook

Vui lòng chạy mã VBA sau để trích xuất địa chỉ email từ trường "Từ" của một hoặc nhiều email đã nhận trong Outlook.

1. Mở một thư mục email, chọn một email mà bạn muốn lấy địa chỉ email của người gửi. Nhấn nút Khác + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

Lời khuyên: Để chọn nhiều email, vui lòng nhấn giữ Ctrl và sau đó chọn từng email một.

2. bên trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp Chèn > Mô-đun, sau đó sao chép mã VBA sau vào cửa sổ Mô-đun (mã).

Mã VBA: trích xuất địa chỉ email của người gửi từ một hoặc nhiều email trong Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. nhấp chuột CÔNG CỤ > dự án, sau đó kiểm tra Thời gian chạy tập lệnh của Microsoft hộp trong Tài liệu tham khảo - Project1 hộp thoại.

4. Nhấn nút F5 phím để chạy mã. Sau đó a Kutools cho Outlook hộp thoại bật lên, liệt kê tất cả các địa chỉ email của người gửi trong số các email đã chọn.

Lời khuyên:

Nếu bạn cần xuất danh sách địa chỉ sang tệp txt, hãy nhấp vào Có .

Hoặc nhấp vào Không nút để kết thúc quá trình.