Làm cách nào để nhập sinh nhật từ Excel sang lịch Outlook?

Nếu bạn có một danh sách dài thông tin sinh nhật trong một trang tính, bây giờ, bạn muốn nhập những sinh nhật này vào lịch Outlook của mình dưới dạng sự kiện. Làm thế nào bạn có thể đối phó với nhiệm vụ này với một số phương pháp nhanh chóng?

Nhập sinh nhật từ Excel sang lịch Outlook với mã VBA

Thông thường, không có cách nào trực tiếp để nhập sinh nhật vào lịch Outlook, ở đây, tôi sẽ tạo mã VBA để giải quyết vấn đề này, vui lòng thực hiện theo các bước sau:

1. Mở trang tính có chứa ngày sinh mà bạn muốn nhập vào Outlook, sau đó nhấn giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Nhấp chuột Chèn > Mô-đunvà dán mã sau vào Cửa sổ mô-đun.

Mã VBA: Nhập sinh nhật vào lịch Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Vẫn trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp CÔNG CỤ > dự án. Trong cửa sổ bật ra Tài liệu tham khảo - VBAProject hộp thoại, kiểm tra Thư viện đối tượng Microsoft Outlook 16.0 tùy chọn hình thành Tài liệu tham khảo có sẵn hộp danh sách, xem ảnh chụp màn hình:

4. Sau đó nhấn vào OK để đóng hộp thoại này. Bây giờ bấm F5 để chạy mã này và một hộp nhắc xuất hiện, vui lòng chọn cột tên và ngày sinh, xem ảnh chụp màn hình:

5. Và sau đó, nhấp vào OK , sinh nhật sẽ được nhập vào lịch Outlook ngay lập tức, bạn có thể khởi chạy Outlook của mình để xem kết quả, xem ảnh chụp màn hình: