Làm thế nào để giữ cho cửa sổ excel luôn ở trên cùng?

Bạn đã bao giờ ước rằng giữ cho cửa sổ Excel của mình luôn ở trên cùng và không bị che bởi các cửa sổ khác? Rất tiếc, Excel không cung cấp một tính năng để giải quyết công việc này. Tuy nhiên, ở đây, tôi có thể cung cấp cho bạn mã VBA để giải quyết công việc này.

Giữ cửa sổ Excel luôn ở trên cùng với mã VBA

Giữ cửa sổ Excel luôn ở trên cùng với mã VBA

Mã VBA sau đây có thể giúp bạn giữ cho cửa sổ Excel luôn ở trên cùng, mã được áp dụng cho cả office 32-bit và office 64-bit.

1. Giữ ALT + F11 phím để mở Cửa sổ Microsoft Visual Basic for Applications.

2. Nhấp chuột Chèn > Mô-đunvà dán mã sau vào Cửa sổ mô-đun.

Mã VBA: Giữ cho cửa sổ Excel luôn ở trên cùng

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

3. Sau đó nhấn F5 phím để chạy mã này và Macros hộp thoại sẽ xuất hiện, chọn SetXLOnTop và nhấp vào chạy .

4. Và khi đó cửa sổ Excel của bạn sẽ luôn ở trên các ứng dụng khác.

Chú thích: Nếu bạn muốn đưa cửa sổ Excel trở lại bình thường, chỉ cần nhấn F5 chìa khóa để mở Macros hộp thoại, chọn SetXNormal và nhấp chạy.