Làm cách nào để in các tác vụ dựa trên danh mục trong Outlook?

Giả sử, có nhiều danh mục màu khác nhau trong nhiệm vụ Outlook của bạn và bây giờ, bạn muốn in danh sách nhiệm vụ dựa trên danh mục trong các trang khác nhau. Làm thế nào bạn có thể giải quyết công việc này trong Outlook?

In các tác vụ dựa trên danh mục trong các trang khác nhau theo cách thủ công từng cái một

In các tác vụ dựa trên các danh mục trong các trang khác nhau với mã VBA

In các tác vụ dựa trên danh mục trong các trang khác nhau theo cách thủ công từng cái một

Trong Outlook, bạn có thể in thủ công các tác vụ dựa trên các danh mục khác nhau trong từng trang khác nhau, vui lòng thực hiện như sau:

1. Khởi chạy Outlook và chuyển đến ngăn Tác vụ và chọn thư mục tác vụ bạn muốn in, sau đó nhấn Ctrl + E để kích hoạt Tìm kiếm hộp, và sau đó dưới Tìm kiếm tab, nhấp vào Phân loại và chọn một danh mục màu bạn cần in, xem ảnh chụp màn hình:

tác vụ in doc theo danh mục 1

2. Và sau đó, tất cả các tác vụ với danh mục màu cụ thể được liệt kê cùng một lúc, hãy xem ảnh chụp màn hình:

tác vụ in doc theo danh mục 2

3. Sau đó, nhấp vào Tập tin > In để in ra danh sách nhiệm vụ này như ảnh chụp màn hình sau:

tác vụ in doc theo danh mục 3

4. Lặp lại các bước trên để in lần lượt danh sách nhiệm vụ với các loại màu khác theo cách thủ công.

In các tác vụ dựa trên các danh mục trong các trang khác nhau với mã VBA

Đây là mã VBA có thể giúp bạn in các tác vụ dựa trên danh mục trong các trang khác nhau cùng một lúc, vui lòng thực hiện theo các bước sau:

1. Đi đến Nhiệm vụ và chọn thư mục tác vụ mà bạn muốn in.

2. Sau đó, nhấn giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

3. Và sau đó, nhấp vào Chèn > Mô-đun, sao chép và dán mã bên dưới vào mô-đun trống đã mở:

Mã VBA: In các tác vụ dựa trên các danh mục trong các trang khác nhau:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Sau đó nhấn vào CÔNG CỤ > dự án trong Microsoft Visual Basic cho các ứng dụng cửa sổ, trong cửa sổ bật ra Tài liệu tham khảo-Dự án1 hộp thoại, kiểm tra Thư viện đối tượng Microsoft Excel và Thời gian chạy tập lệnh của Microsoft các tùy chọn từ Tài liệu tham khảo có sẵn hộp danh sách, xem ảnh chụp màn hình:

tác vụ in doc theo danh mục 4

5. Và sau đó, nhấp vào OK nút, bây giờ, nhấn F5 để chạy mã này, sau khi kết thúc mã, danh sách các nhiệm vụ với các hạng mục khác nhau sẽ được in ra các trang khác nhau.