Phương pháp này sẽ giới thiệu một VBA để xuất danh sách tất cả các thư mục và các thư mục con của chúng trong một tài khoản email được chỉ định thành một email mới trong Outlook và sau đó bạn có thể in danh sách các thư mục một cách dễ dàng.

1. nhấn Khác + F11 để mở cửa sổ Microsoft Visual Basic for Applications.

2. nhấp chuột Chèn > Mô-đun, rồi dán mã VBA bên dưới vào cửa sổ Mô-đun mới.

VBA: Xuất danh sách các thư mục và thư mục con trong một email mới trong Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.mailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)

Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

    For i = CurrentFolder.Folders.Count To 1 Step -1
Set oFolder = CurrentFolder.Folders(i)

sFolderPaths = oFolder.FolderPath
gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
If oSubFolder.Name <> "Deleted Items" Then
ProcessFolder oSubFolder
End If

Next

End Sub

3. nhấn F5 để chạy VBA này.

4. Trong hộp thoại Chọn thư mục hiện ra, vui lòng chọn tài khoản email có danh sách thư mục bạn muốn in và nhấp vào OK cái nút. Xem ảnh chụp màn hình:

5. Và bây giờ danh sách thư mục của tài khoản email được chỉ định được sao chép sang một email mới như hình minh họa bên dưới. Vui lòng bấm vào Tập tin > In để in danh sách thư mục đã sao chép.

6. Sau khi in xong, vui lòng đóng email mới không lưu.

Phương pháp này sẽ giới thiệu một VBA để xuất danh sách tất cả các thư mục và các thư mục con của chúng trong một tài khoản email được chỉ định từ Outlook sang Notepad và sau đó bạn có thể in danh sách các thư mục Outlook trong Notepad một cách dễ dàng.

1. nhấn Khác + F11 để mở cửa sổ Microsoft Visual Basic for Applications.

2. nhấp chuột Chèn > Mô-đun, rồi dán mã VBA bên dưới vào cửa sổ Mô-đun mới.

VBA: Xuất danh sách tất cả thư mục Outlook và thư mục con từ Outlook sang Notepad

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

  Set objOutlook = CreateObject("Outlook.Application")

  Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
Set Folders = F.Folders

    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
If Result = 6 Then
gCreateTree = True
Else
gCreateTree = False
End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))

LoopFolders Folders

Set F = Nothing
Set Folders = Nothing
Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F

For Each F In Folders
WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
CreateFolderTree = Mid(OLKfolderpath, 3)
Else
Dim i, x, OLKprefix
i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))

    For x = gBase To i
OLKprefix = OLKprefix & "-"
Next

CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. nhấn F5 để chạy VBA này. Tiếp theo trong hộp thoại Chọn thư mục đang mở, vui lòng chọn tài khoản email có danh sách thư mục bạn muốn xuất và in, và nhấp vào OK cái nút. Xem ảnh chụp màn hình:

4. Sau đó xuất hiện hộp thoại Output Folder Tree. Vui lòng nhấp vào Có nút hoặc Không khi bạn cần.

Và bây giờ một tệp Văn bản có tên là Thư mục Outlook được tạo và lưu trên màn hình của bạn như hình minh họa bên dưới.

5. Bấm đúp để mở tệp văn bản mới, sau đó bấm Tập tin > In để in danh sách thư mục outlook đã xuất.

Một cú nhấp chuột để hiển thị tổng số mục trong tất cả các thư mục trên Ngăn Dẫn hướng trong Outlook

Thông thường, Outlook hiển thị số lượng các mục chưa đọc trong mỗi thư mục trên Ngăn Dẫn hướng. Nhưng, Kutools cho Outlook's Tất cả các thư mục Hiển thị tổng số mục tính năng này có thể giúp bạn hiển thị tổng số mục trong tất cả các thư mục chỉ với một cú nhấp chuột.

Hiển thị hoặc ẩn dạng xem danh sách thư mục trong Outlook