Excel CHOOSE chức năng

Mô tả

Cú pháp và đối số

Cách sử dụng và các ví dụ

• Ex1 - Cách sử dụng cơ bản: using CHOOSE một mình chức năng để chọn giá trị từ đối số danh sách
• Ex2 - Trả về các kết quả khác nhau dựa trên nhiều điều kiện
• Ex3 - Trả về các kết quả được tính toán khác nhau dựa trên các điều kiện
• Ex4 - Chọn ngẫu nhiên từ danh sách
• Ex5 - Kết hợp CHOOSE và VLOOKUP hàm trả về giá trị trong cột bên trái
• Ex6 - Trả về ngày trong tuần hoặc tháng dựa trên ngày nhất định
• Ex7 - Quay lại ngày làm việc / ngày cuối tuần tiếp theo dựa trên hôm nay

---

Mô tả

Mô hình CHOOSE hàm trả về một giá trị từ danh sách đối số giá trị dựa trên số chỉ mục đã cho. Ví dụ, CHOOSE(3,”Apple”,”Peach”,”Orange”) trả về màu cam, số chỉ mục là 3 và màu cam là giá trị thứ ba sau số chỉ mục trong hàm.

cú pháp và đối số

Cú pháp công thức

CHOOSE(index_num, value1, [value2], …)

Lập luận

Index_num: Cần thiết. Một giá trị số từ 1-254 đến gián tiếp mà giá trị đối số sẽ được chọn. nếu index_num nằm ngoài tỷ lệ từ 1-254, CHOOSE trả lại #VALUE! giá trị lỗi. Nếu index_num là một giá trị thập phân, nó sẽ được làm tròn xuống một số nguyên trước khi công thức được sử dụng. Value1: Cần thiết. Giá trị đầu tiên trong công thức có thể được chọn. Value2: Không bắt buộc. Giá trị thứ hai và tối đa thứ 254 để chọn.

Value1, value2… Có thể là số, văn bản, công thức, tham chiếu ô hoặc tên đã xác định.

Trở lại giá trị

Mô hình CHOOSE hàm trả về một giá trị từ một danh sách dựa trên vị trí đã cho.

Cách sử dụng và các ví dụ

Trong phần này, tôi liệt kê một số ví dụ đơn giản nhưng tiêu biểu để giải thích việc sử dụng CHOOSE chức năng.

Ex1 - Cách sử dụng cơ bản: using CHOOSE một mình chức năng để chọn giá trị từ đối số danh sách

Công thưc 1:

=CHOOSE(3,"a","b","c","d")

Return: c, là đối số thứ ba sau index_num của 3 trong CHOOSE chức năng.

Lưu ý: sử dụng dấu ngoặc kép bao quanh giá trị nếu nó là văn bản.

Công thưc 2:

=CHOOSE(2,A1,A2,A3,A4)

Trả về: Kate, giá trị của A2. Vì index_num là 2 và A2 là giá trị thứ hai trong CHOOSE chức năng.

Công thưc 3:

=CHOOSE(4,8,9,7,6)

Return: 6, đối số danh sách thứ 4 trong hàm.

---

Ex2 - Trả về các kết quả khác nhau dựa trên nhiều điều kiện

Giả sử bạn có một danh sách các độ lệch cho từng sản phẩm cần được dán nhãn dựa trên các điều kiện như hình minh họa bên dưới.

Thông thường, bạn có thể sử dụng hàm IF để xử lý, nhưng ở đây tôi giới thiệu cách sử dụng CHOOSE chức năng để giải quyết vấn đề này một cách dễ dàng

Công thức:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

giải thích:

(B7>0)+(B7>1)+(B7>5): index_num, B7 là 2, lớn hơn 0 và 1 nhưng nhỏ hơn 5, vì vậy chúng tôi nhận được kết quả trung gian:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Như chúng ta biết, True = 1, False = 0, vì vậy công thức có thể được xem như:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

sau đó

=CHOOSE(2,"Top","Middle","Bottom")

Kết quả: Trung bình

---

Ex3 - Trả về các kết quả được tính toán khác nhau dựa trên các điều kiện

Giả sử bạn cần tính toán các khoản giảm giá cho mỗi sản phẩm dựa trên số lượng và giá cả như ảnh chụp màn hình dưới đây:

Công thức:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

giải thích:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 là 102, lớn hơn 100 nhưng nhỏ hơn 201, vì vậy trong phần này, nó trả về kết quả như sau:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

sau đó

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: các giá trị để chọn, giảm giá tương đương với giá * số tiền * phần trăm giảm giá, vì ở đây index_num là 2, nó chọn B8 * C8 * 0.2

Lợi nhuận: 102 * 2 * 0.2 = 40.8

---

Ex4 - Chọn ngẫu nhiên từ danh sách

Trong Excel, đôi khi, bạn có thể cần phải chọn ngẫu nhiên một giá trị từ một danh sách nhất định, CHOOSE chức năng có thể giải quyết công việc này.

Chọn ngẫu nhiên một giá trị từ danh sách:

Công thức:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

giải thích:

RANDBETWEEN(1,5): index_num, lấy ngẫu nhiên số từ 1 đến 5

$D$2,$D$3,$D$4,$D$5,$D$6: danh sách các giá trị để chọn

---

Ex5 - Kết hợp CHOOSE và VLOOKUP hàm trả về giá trị trong cột bên trái

Nói chung, chúng tôi sử dụng hàm VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) để trả về một giá trị dựa trên một giá trị nhất định từ một phạm vi bảng. Nhưng với VLOOKUP , nó sẽ trả về một giá trị lỗi trong khi cột trả về ở bên trái của cột tra cứu như hình minh họa bên dưới:

Trong trường hợp này, bạn có thể kết hợp CHOOSE chức năng với hàm VLOOKUP để giải quyết vấn đề.

Công thức:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

giải thích:

CHOOSE({1,2},B1:B7,A1:A7): làm đối số table_range trong hàm VLOOKUP. {1,2} có nghĩa là hiển thị 1 hoặc 2 dưới dạng đối số index_num dựa trên đối số col_num trong hàm VLOOKUP. Ở đây, col_num trong hàm VLOOKUP là 2, vì vậy CHOOSE chức năng hiển thị như CHOOSE(2, B1:B7,A1:A7), nghĩa là chọn giá trị từ A1: A7.

---

Ex6 - Trả về ngày trong tuần hoặc tháng dựa trên ngày nhất định

Với CHOOSE , bạn cũng có thể trả về ngày và tháng tương đối dựa trên một ngày nhất định.

Công thức 1: trở lại ngày trong tuần trước một ngày

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

giải thích:

WEEKDAY(): đối số index_num, để nhận số ngày trong tuần của ngày đã cho, ví dụ: WEEKDAY (A5) trả về 6, thì đối số index_num là 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": đối số danh sách giá trị, bắt đầu bằng “Chủ nhật” vì số “1” trong ngày cho biết “Chủ nhật”.

Công thức 2: trở lại tháng trước một ngày

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

giải thích:

MONTH(): Đối số index_num, lấy số tháng từ ngày đã cho, ví dụ: MONTH (A5) trả về 3.

---

Ex7 - Quay lại ngày làm việc / ngày cuối tuần tiếp theo dựa trên hôm nay

Trong công việc hàng ngày, bạn có thể muốn tính ngày làm việc tiếp theo hoặc ngày cuối tuần dựa trên ngày hôm nay. Đây CHOOSE chức năng cũng có thể giúp bạn.

Ví dụ, hôm nay là ngày 12/20/2018, thứ Năm, bây giờ bạn cần có ngày làm việc và cuối tuần tiếp theo.

Công thức 1: lấy ngày hôm nay

=TODAY()

Kết quả: 12/20/2018

Công thức 2: lấy số ngày trong tuần của hôm nay

=WEEKDAY(TODAY())

Kết quả: 5 (trong khi hôm nay là 12/20/2018)

Danh sách số ngày trong tuần như ảnh chụp màn hình bên dưới:

Công thức 3: có được ngày làm việc tiếp theo

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

giải thích:

Today(): trả lại ngày hiện tại

WEEKDAY(TODAY()): đối số index_num trong CHOOSE , lấy số ngày trong tuần của hôm nay, ví dụ: Chủ nhật là 1, Thứ hai là 2…

1,1,1,1,1,3,2: đối số danh sách giá trị trong CHOOSE chức năng. Ví dụ: nếu ngày trong tuần (hôm nay ()) trả về 1 (Chủ nhật), nó chọn 1 dạng danh sách các giá trị, sau đó toàn bộ công thức chuyển thành = Hôm nay () + 1, có nghĩa là thêm 1 ngày để trả về Thứ Hai tuần sau. Nếu ngày trong tuần (hôm nay ()) trả về 6 (thứ sáu), nó sẽ chọn 3 từ danh sách các giá trị, vì thứ sáu cách thứ hai tuần tới 3 ngày.

Kết quả (trong khi hôm nay là 12/20/2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Công thức 4: đón ngày cuối tuần tiếp theo

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

giải thích:

6,5,4,3,2,1,1: đối số danh sách giá trị trong CHOOSE chức năng. Ví dụ: nếu ngày trong tuần (hôm nay ()) trả về 1 (Chủ nhật), nó chọn 6 từ danh sách các giá trị, thì toàn bộ công thức sẽ thay đổi thành = Hôm nay () + 6, có nghĩa là thêm 6 ngày và trả về thứ Bảy tới.

Kết quả:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

Tệp mẫu